Shader "Custom/Chapter9-ForwardRendering" {
	Properties {
		//漫反射颜色
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
		//高光反射系数,用于控制材质的高光反射颜色
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		//光泽度(反射度)，用于控制高光区域的大小,值越大，亮点越小
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {
		Pass {
			Tags { "LightMode"="ForwardBase" }
			
			CGPROGRAM
			#pragma multi_compile_fwdbase
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};
			
			v2f vert(a2v v) {
				v2f o;
				//把顶点位置从模型空间转换到裁剪空间
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				//把模型法线从模型空间转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)_World2Object);
				//把顶点坐标从模型空间转换到世界空间
				o.worldPos = mul(_Object2World, v.vertex).xyz;
				return o;
			}
			
			//Blinn-Phong光照模型
			fixed4 frag(v2f i) : COLOR
			{
				//========================漫反射代码=========================
				//得到环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldNormal = normalize(i.worldNormal);
				//光源方向
				//这种获取方式只适合场景中只有一个平行光的情况
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				
				//对于Bass Pass来说，它处理的逐像素光源类型一定是平行光。
				//如果场景中包含多个平行光，Unity会选择最亮的平行光传递给Base Pass进行逐像素处理,
				//其他平行光会按照逐顶点或在Additional Pass中按逐像素的方式处理。
				//如果场景中没有任何平行光，那么Base Pass会当成全黑的光源处理。
				//每一个光源有5个属性：位置、方向、颜色、强度以及衰减。
				//我们可以使用_WorldSpaceLightPos0来得到这个平行光的方向(位置对于平行光来说没有意义),
				//使用_LightColor0来得到它的颜色和强度(_LightColor0已经是颜色和强度相乘后的结果)，由于
				//平行光可以认为是没有衰减的，因此这里我们直接令衰减值为1.0
				
				//漫反射公式
				//_LightColor0: 光源的颜色和强度信息(注意,想要得到正确的值需要定义合适的LightMode标签)
				//_Diffuse: 材质的漫反射系数
				//saturate(x): 把x截取在[0,1]范围内，如果x是个矢量，那么会对它的每一个分量进行这样的操作。
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
				//============================End============================
				
				//========================高光反射代码=========================
				//通过入射光矢量与模型法线计算出反射光矢量
				fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
				//计算视角方向
				//_WorldSpaceCameraPos: 世界空间中的摄像机位置
				//_Object2World: 模型空间到世界空间的转换矩阵
				//视角方向 = 摄像机位置 - 模型顶点在世界空间中的位置
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				//_LightColor0: 入射光线的颜色和强度
				//_Specular: 高光反射系数
				//_Gloss: 材质的光泽度(反光度),值越大，亮点越小。
				//reflectDir: 反射光方向
				//viewDir: 视角方向
				fixed3 specular = _LightColor0.rgb*_Specular.rgb*pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				//============================End============================
				
				//平行光的衰减值总是为1.0
				fixed atten = 1.0;
				
				return fixed4(ambient + (diffuse + specular) * atten, 1.0);
			}
			
			ENDCG
		}
		
		Pass {
			Tags { "LightMode"="ForwardAdd" }
			
			//开启混合模式
			//我们希望Additional Pass计算得到的光照结果可以在帧缓存中与之前的光照结果进行叠加。
			//没有Blend命令的话，Additional Pass会直接覆盖掉之前的光照结果。
			//可以设置成Unity支持的任何混合系数，常见的还有Blend SrcAlpha One
			Blend One One
			
			CGPROGRAM
			//multi_compile_fwdadd指令可以保证我们访问到正确的光照变量
			#pragma multi_compile_fwdadd
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				LIGHTING_COORDS(2, 3)
			};
			
			v2f vert(a2v v) {
				v2f o;
				//把顶点位置从模型空间转换到裁剪空间
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				//把模型法线从模型空间转换到世界空间
				o.worldNormal = mul(v.normal, (float3x3)_World2Object);
				//把顶点坐标从模型空间转换到世界空间
				o.worldPos = mul(_Object2World, v.vertex).xyz;
				
				TRANSFER_VERTEX_TO_FRAGMENT(o);
				return o;
			}
			
			//Blinn-Phong光照模型
			fixed4 frag(v2f i) : COLOR
			{
				//通常来说，Additional Pass的光照处理和Base Pass的处理方式是一样的，因此我们只需
				//要把Base Pass的顶点和片元着色器代码粘贴到Additional Pass中，然后再稍微修改一下即可。
				//这些修改往往是为了去掉Base Pass中环境光、自发光、逐顶点光照、SH光照的部分，并添加一些
				//对不同光源类型的支持。因此，在Additional Pass的片元着色器中，我们没有再计算场景中的环境光。
				//由于Additional Pass处理的光源类型可能是平行光、点光源或是聚光灯，因此在计算光源的5个属性
				//——位置、方向、颜色、强度以及衰减时，颜色和强度我们仍然可以使用_LightColor0来得到，但对于位置、
				//方向和衰减性，我们就需要根据光源类型分别计算。
			
				//========================漫反射代码=========================
				//得到环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldNormal = normalize(i.worldNormal);
				//光源方向
				#ifdef USING_DIRECTIONAL_LIGHT
					//平行光
					fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				#else
					//点光源或聚光灯
					//_WorldSpaceLightPos0.xyz表示的是世界空间下的光源位置
					//i.worldPosition.xyz表示世界空间下的顶点位置
					fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);
				#endif
				
				//漫反射公式
				//_LightColor0: 光源的颜色和强度信息(注意,想要得到正确的值需要定义合适的LightMode标签)
				//_Diffuse: 材质的漫反射系数
				//saturate(x): 把x截取在[0,1]范围内，如果x是个矢量，那么会对它的每一个分量进行这样的操作。
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
				//============================End============================
				
				//========================高光反射代码=========================
				//通过入射光矢量与模型法线计算出反射光矢量
				fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
				//计算视角方向
				//_WorldSpaceCameraPos: 世界空间中的摄像机位置
				//_Object2World: 模型空间到世界空间的转换矩阵
				//视角方向 = 摄像机位置 - 模型顶点在世界空间中的位置
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				//_LightColor0: 入射光线的颜色和强度
				//_Specular: 高光反射系数
				//_Gloss: 材质的光泽度(反光度),值越大，亮点越小。
				//reflectDir: 反射光方向
				//viewDir: 视角方向
				fixed3 specular = _LightColor0.rgb*_Specular.rgb*pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				//============================End============================
				

				//直接用Unity提供的辅助宏获取光照衰减值
				fixed atten = LIGHT_ATTENUATION(i);
				
				return fixed4(ambient + (diffuse + specular) * atten, 1.0);
			}
			ENDCG
		}
	} 
	FallBack "Diffuse"
}

效果