使用一张纹理来代替物体的漫反射颜色。

Shader代码

Shader "Custom/Chapter7-SingleTexture" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {
		Pass {
			Tags { "LightMode"="ForwardBase" }

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			//在Unity中，我们需要使用 纹理名_ST 的方式来声明某个纹理的属性。
			//其中，ST是缩放(scale)和平移(translation)的缩写。
			//_MainTex_ST可以让我们得到该纹理的缩放和平移(偏移)值
			//_MainTex_ST.xy存储的是缩放值
			//_MainTex_ST.zw存储的是偏移值。
			//这些值可以在材质面板的纹理属性中调节。
			float4 _MainTex_ST;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				//Unity会将模型的第一组纹理坐标存储到该变量中
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				o.worldNormal = mul(v.normal, (float3x3)_World2Object);
				//Unity5中可用UnityObjectToWorldNormal()函数得到o.worldNormal
				//o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(_Object2World, v.vertex).xyz;
				o.uv = v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
				//或者调用Unity内建的函数计算o.uv
				//o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}
			//Unity5中返回的语义用SV_Target
			//Unity4中返回的语义用COLOR
			fixed4 frag(v2f i) : COLOR {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				//Unity5中可用UnityWorldSpaceLightDir()函数得到worldLightDir
				//fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				//_Color在这里控制物体的整体色调
				//材质的反射率
				fixed3 albedo = tex2D(_MainTex, i.uv).rgb*_Color.rgb;
				//环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
				//漫反射光照
				fixed3 diffuse = _LightColor0.rgb*albedo*max(0, dot(worldNormal, worldLightDir));
				//视觉方向
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				//Unity5中可用UnityWorldSpaceViewDir()函数得到viewDir
				//fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				
				//半兰伯特光照方向
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				//半兰伯特高光反射
				fixed3 specular = _LightColor0.rgb*_Specular.rgb*pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				
				return fixed4(ambient+diffuse+specular, 1.0);
			}

			ENDCG
		}
	} 
	FallBack "Diffuse"
}

效果一

效果二
Color Tint: 控制物体整体色调
Base(RGB)
Tiling: 控制纹理缩放
Offset: 控制纹理偏移
Specular: 控制亮点颜色
Gloss: 控制亮点大小