兰伯特光照模型Shader代码之逐顶点光照

Shader "Custom/Chapter6-DiffuseVertexLevel" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
	}
	SubShader {
		pass{
			Tags { "LightMode"="ForwardBase" }
			
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			
			fixed4 _Diffuse;
			
			struct a2v {
				float4 vertex : POSITION;
				//存储模型的顶点法线信息
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				//需要把顶点颜色传给片元着色器
				fixed3 color : COLOR;
			};

			//漫反射光照模型——逐顶点光照
			v2f vert(a2v v) {
				v2f o;
				//把顶点位置从模型空间转换到裁剪空间
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				//得到环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				//把顶点法线从模型空间转换到世界空间
				//_World2Object: 顶点变换矩阵的逆转置矩阵,这里取矩阵的前三行前三列。
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)_World2Object));
				//光源方向
				//这种获取方式只适合场景中只有一个平行光的情况
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				//漫反射公式
				//_LightColor0: 光源的颜色和强度信息(注意,想要得到正确的值需要定义合适的LightMode标签)
				//_Diffuse: 材质的漫反射系数
				//saturate(x): 把x截取在[0,1]范围内，如果x是个矢量，那么会对它的每一个分量进行这样的操作。
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
				//标准光照模型：直接加上环境光
				o.color = ambient + diffuse;
				return o;
			}
			
			fixed4 frag(v2f i) : COLOR {
				return fixed4(i.color, 1.0);
			}
			ENDCG
		}
	} 
	FallBack "Diffuse"
}

效果